在xsl的节点和子节点中将文本转换为小写

更新时间：2023-02-08 22:22:10

此转换会产生所需的标点符号，以分隔单词：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="head//text()">
  <xsl:analyze-string select="." regex="\p{{L}}+">
   <xsl:matching-substring>
     <xsl:value-of select=
      "concat(upper-case(substring(.,1,1)), lower-case(substring(.,2)))"/>
   </xsl:matching-substring>
   <xsl:non-matching-substring>
    <xsl:value-of select="."/>
   </xsl:non-matching-substring>
  </xsl:analyze-string>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档时：

<text> text text text
 <head>BLAH <unkownTag>BLAH</unkownTag> BLAH </head>
</text>

产生了所需的正确结果：

<text> text text text
 <head>Blah <unkownTag>Blah</unkownTag> Blah </head>
</text>

在此XML文档上应用时：

<text> text text text
 <head>BLAH$<unkownTag>BLAH</unkownTag>-BLAH;</head>
</text>

再次产生正确的结果：

<text> text text text
 <head>Blah$<unkownTag>Blah</unkownTag>-Blah;</head>
</text>

说明：

正确使用 < xsl：analyze-string> 指令。

正确使用 \p {L} 字符类。

正确使用 < xsl：matching-substring> 和 < xsl：non-matching-substring> 指令。

上一篇 : ：SQL:如何选择物化路径中的所有父节点?下一篇 : XSLT/XPath 中的当前节点与上下文节点?

在xsl的节点和子节点中将文本转换为小写

相关阅读

技术问答最新文章