I.这是一个简单而自然的 XSLT 2.0 解决方案:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*/*">
  <xsl:value-of separator=", " select=
  "substring-before(., ',')
   , for $n in tokenize(substring-after(., ','), '\s')[.]
        return
          substring($n, 1,1)
  "/>
  <xsl:text>&#xA;</xsl:text>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时:

<t xmlns:dc="some:dc">
 <dc:creator >Friend, Natasha</dc:creator>

 <dc:creator>Tolkien, J. R. R.</dc:creator>
</t>

产生了想要的、正确的结果:

Friend, N
Tolkien, J., R., R.

二.XSLT 1.0 解决方案:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*/*/text()">
   <xsl:value-of select="substring-before(., ',')"/>

   <xsl:call-template name="replaceTokenDelims">
    <xsl:with-param name="pStr" select=
    "concat(normalize-space(substring-after(., ',')), ' ')"/>
    <xsl:with-param name="pToken" select="' '"/>
    <xsl:with-param name="pReplacement" select="', '"/>
   </xsl:call-template>
   <xsl:text>&#xA;</xsl:text>
 </xsl:template>

 <xsl:template name="replaceTokenDelims">
    <xsl:param name="pStr"/>
    <xsl:param name="pToken"/>
    <xsl:param name="pReplacement"/>

    <xsl:if test="$pStr">
     <xsl:value-of select="$pReplacement"/>
     <xsl:value-of select=
      "substring(substring-before($pStr, $pToken), 1, 1)"/>

     <xsl:call-template name="replaceTokenDelims">
      <xsl:with-param name="pStr"
           select="substring-after($pStr, $pToken)"/>
      <xsl:with-param name="pToken" select="$pToken"/>
      <xsl:with-param name="pReplacement" select="$pReplacement"/>
     </xsl:call-template>
    </xsl:if>
 </xsl:template>
</xsl:stylesheet>

当这个转换应用于同一个 XML 文档(上图)时，同样会产生相同的正确结果:

Friend, N
Tolkien, J., R., R.